1 | ****************************************
|
---|
2 | * - F A D E - *
|
---|
3 | * Cette routine passe de la palette de *
|
---|
4 | * couleurs courante à celle stockée en *
|
---|
5 | * $DFE0 en réalisant un fondu enchaîné *
|
---|
6 | ****************************************
|
---|
7 | *Laurent Hiriart, 67420 COLROY-la-ROCHE*
|
---|
8 | ****************************************
|
---|
9 |
|
---|
10 | DIR EQU ENDPRG/256
|
---|
11 | V EQU ENDPRG-DIR*256
|
---|
12 | NPASS EQU V nombre d'étapes
|
---|
13 | NCOLOR EQU V+1 No couleur traitée
|
---|
14 | ACTUEL EQU V+2 sa palette courante
|
---|
15 | BLEU EQU V+4 hauteur de Bleu
|
---|
16 | VERT EQU V+5 hauteur de Vert
|
---|
17 | ROUGE EQU V+6 hauteur de Rouge
|
---|
18 |
|
---|
19 | WAIT EQU 1 Attente entre 2 étapes
|
---|
20 |
|
---|
21 | ORG $DF58
|
---|
22 | G PSHS X,B,A,DP,CC
|
---|
23 | LDD #$1000+DIR accès direct
|
---|
24 | TFR B,DP aux "variables"
|
---|
25 | STA <NPASS
|
---|
26 | LDU #$E7DA +rapide & +concis
|
---|
27 |
|
---|
28 | APPEAR LDD #$1E00+WAIT
|
---|
29 | TST 13,U
|
---|
30 | BPL *-2 attend le retour
|
---|
31 | TST 13,U du spot sur la
|
---|
32 | BMI *-2 ligne 200.
|
---|
33 | DECB
|
---|
34 | BNE APPEAR+3
|
---|
35 | LDX #8*45 descend bien bas
|
---|
36 | LEAX -1,X dans le border
|
---|
37 | BNE *-2
|
---|
38 | LDX #COLORS+32
|
---|
39 | STA <NCOLOR
|
---|
40 |
|
---|
41 | PALETT LDA ,-X palette finale
|
---|
42 | ANDA #15
|
---|
43 | STA <ROUGE hauteurs de rouge,
|
---|
44 | LDD ,-X
|
---|
45 | ANDA #15
|
---|
46 | ANDB #240
|
---|
47 | STD <BLEU de bleu et de vert
|
---|
48 |
|
---|
49 | LDA <NCOLOR 2*No de la couleur
|
---|
50 | STA 1,U
|
---|
51 | LDB ,U palette courante
|
---|
52 | LDA ,U de la couleur
|
---|
53 | ANDA #15 courante
|
---|
54 | STD <ACTUEL
|
---|
55 |
|
---|
56 | COMPO1 LDA <ACTUEL+1
|
---|
57 | ANDB #15
|
---|
58 | CMPB <ROUGE (ajuste le rouge)
|
---|
59 | BHI SUBROU
|
---|
60 | BEQ COMPO2
|
---|
61 | ADDA #2 Quelques octets de
|
---|
62 | SUBROU DECA moins à recopier
|
---|
63 |
|
---|
64 | COMPO2 LDB <ACTUEL+1
|
---|
65 | ANDB #240
|
---|
66 | CMPB <VERT (ajuste le vert)
|
---|
67 | BHI SUBVER
|
---|
68 | BEQ COMPO3
|
---|
69 | ADDA #32 c'est déjà ça d'é-
|
---|
70 | SUBVER SUBA #16 pargné au lecteur
|
---|
71 |
|
---|
72 | COMPO3 STA <ACTUEL+1
|
---|
73 | LDA <ACTUEL
|
---|
74 | CMPA <BLEU (ajuste le bleu)
|
---|
75 | BHI SUBBLE
|
---|
76 | BEQ FINCOU
|
---|
77 | ADDA #2 de Micro-News qui
|
---|
78 | SUBBLE DECA recopie mes DATAS.
|
---|
79 |
|
---|
80 | FINCOU LDB <NCOLOR
|
---|
81 | STB 1,U
|
---|
82 | LDB <ACTUEL+1
|
---|
83 | STB ,U validation de la
|
---|
84 | STA ,U nouvelle palette
|
---|
85 | DEC <NCOLOR
|
---|
86 | DEC <NCOLOR couleur suivante
|
---|
87 | BPL PALETT ...
|
---|
88 |
|
---|
89 | DEC <NPASS étape suivante ...
|
---|
90 | BNE APPEAR
|
---|
91 | PULS CC,DP,A,B,X,U,PC on sort
|
---|
92 |
|
---|
93 | ENDPRG FCB 0,0,0,0,0,0,0 "variables"
|
---|
94 | FCC "HCL" *-> Lg multiple de 8
|
---|
95 | COLORS * nouvelles palettes stockées ici
|
---|
96 |
|
---|
97 | END
|
---|