VIDEO.ASM@ ceffc47

main

Last change on this file since ceffc47 was ceffc47, checked in by Adrien Destugues <pulkomandy@…>, 10 years ago

Add that collection of 3rdparty source I had lying on my disk for some time...

git-svn-id: svn://localhost/thomson@51 85ae3b6b-dc8f-4344-a89d-598714f2e4e5

File size: 2.2 KB

Line
1	****************************************
2	* V I D E O *
3	* Aujourd'hui j'ai fait joujou avec *
4	* $E7E7, et c'est follement amusant. *
5	* *
6	* Un tube qui déforme l'écran là où *
7	* il passe ? (Joystick0) It's ovcourse *
8	* another cool trick from Doctor Lô ! *
9	****************************************
10
11	ORG $9000
12	RGB EQU $100
13
14	G ORCC #80
15	PSHS DP
16	LDA #$E7
17	TFR A,DP
18
19	LDA #32
20	BITA <$E7
21	BEQ *-2
22	BITA <$E7
23	BNE *-2
24	PSHS A
25	MUL
26	MUL
27	MUL
28	MUL
29	PULS A
30	BITA <$E7
31	BEQ *-10
32	MUL
33	MUL
34	MUL
35	MUL
36	MUL
37	TST <$E7
38	BPL *-7
39	MUL
40	MUL
41	MUL
42	MUL
43	MUL
44	TST <$E7
45	BMI *-7
46	LDX #1598
47	LEAX -1,X
48	BNE *-2
49
50	LDB #$5C France
51	LDA #$7C Export
52
53	GOON STA <$E7
54
55	LDX #12
56	LIGHT CLRA 2
57	STA <$DB 4
58	LDD #RGB 3
59	STB <$DA 4
60	STA <$DA 4
61	ADDD #RGB 4
62	STD LIGHT+4 6
63	MUL 11
64	MUL 11
65	LDA 1,X 5
66	LDA #$5C 2
67	LEAX -1,X 5
68	BNE LIGHT 3
69
70	STA <$E7
71	MUL
72	MUL
73	MUL
74	MUL
75	MUL
76	NOP
77	LDX #11
78	DARK CLRA 2
79	STA <$DB 4
80	LDD #10*RGB 3
81	STB <$DA 4
82	STA <$DA 4
83	SUBD #RGB 4
84	STD DARK+4 6
85	MUL 11
86	MUL 11
87	LDA 1,X 5
88	LDA #$7C 2
89	LEAX -1,X 5
90	BNE DARK 3
91
92	LDX #RGB
93	STX LIGHT+4
94	LDX #10*RGB
95	STX DARK+4
96	LDB 1,X
97	LDX #2296
98	LDB <$CC
99	BITB #1
100	BEQ *+5
101	NOP
102	BRA *+4
103	LEAX -8,X
104	BITB #2
105	BEQ *+5
106	NOP
107	BRA *+4
108	LEAX 8,X
109	LEAX -1,X
110	BNE *-2
111	LDB <$C8
112	BEQ GOON
113
114	RDP
115	CLRA
116	LDX #0
117	LEAY ,X
118	JSR $EC00
119	PULS DP
120	SWI
121
122	END

Note: See TracBrowser for help on using the repository browser.